***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jan 22, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PJGBLC03 A K 
.param
+vc0 = 4.106e-9		vc1 = 4.956e-9		vc2 = 1.000		vc3 = 2.865e-11		vc4 = 1.081e+1
+tc1 = 5.881e-2		tc2 = 3.811e-2		tc3 = 8.601e-3		tc4 = 6.021e-3
.func irpwr(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*v^vc4)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irpwr(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 1.655e-12	   n = 1.065		  rs = 1.172e-0
+ibv = 0.01e-3		 nbv = 6.0		  bv = 5.0
+ikf = 1.264e-4
***** capacitance parameter *****
+cjo = 8.162e-13	   m = 1.301e-2		  vj = 3.905e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.055		 xti = 3
+trs1 = 1.445e-3	trs2 = 5.806e-6		tikf = 5e-3
+tbv1 = 1.670e-4	tbv2 = 1.086e-5	
.ends PJGBLC03
*$
